附錄B DOES/MAKE 的定義─────────────────────────────────────── 如果你的符式系統中沒有『DOER』和『MAKE』的定義，這個附錄就是用來幫助你建立並 了解它們的。因為這些是與系統相關的字，我在後面列出了一些不同的實現方式，希望 其中有你能夠用上的一種。如果沒有，而且這裏所提供給你的資料也不足以讓它們在 你的系統中動起來，那你也許有著一個很獨特的符式系統。請你去找那個系統的製造商 幫忙。 它工作方式是這樣的：DOER 是一個定義字，它會在詞典中建出一個字（稱為DOER的 孩子，又稱為DOER字），這個字的參數區欄位（一個cell的大小）存放著一個向量地址， 它被初設為指著一個什麼也不做的字『NOTHING』。 DOER 的孩子會執行 DOER 定義中的 DOES> 部份的碼，而這段碼只做二件事：讀取 這個向量地址，並且放到返回堆疊上。符式接下來就會執行這個地址所指著的碼，也 就是被這個向量所指著的功能。這就像是（在83標準中）鍵入： ' NOTHING >BODY >R 的方式來執行『NOTHING』這個字。（這種執行方式只能使用在當NOTHING是個高階字的 情況下。） 下面是我們鍵入『DOER JOE』後，詞典內這部份的圖示， DOER JOE
┌──┬───────┬──────┐
│ │point to │ pfa of │
│JOE │DOES> of DOER │ NOTHING │
└──┴───────┴──────┘
頭部 執行區欄位 參數區欄位
現在，假設我們定義 : TEST MAKE JOE CR ; 也就是，我們定義了一個字，它能使 JOE 重新指向，去執行『CR』的動作。 下面是 TEST 這個定義在詞典中的圖示， ┌──┬────┬──┬───┬───┬───┐
│ │ cfa of │ │cfa of│cfa of│cfa of│
│TEST│ (MAKE) │ 0 │JOE │CR │EXIT │
└──┴────┴──┴───┴───┴───┘
頭部 adr1 adr2 adr3
讓我們先檢視 MAKE 的程式碼。因為我們是在一個冒號定義中使用 MAKE ，所以這時 的 STATE 在"真"的狀態，因此就會執行下面這段片語： COMPILE (MAKE) HERE MARKER ! 0 , 我們看出 MAKE 編入了一個執行時區的常式 (MAKE) 及一個 0。（稍後我們再解釋0的用 途，及為什麼要將它的地址存到變數 MARKER 內）。 現在讓我們看看，在執行 TEST 這個字時，(MAKE) 做了什麼。 R> 從返回堆疊取得地址，它就是在 (MAKE) 之後， 存放著0的那個地址adr1。 DUP 2+ 取得 (MAKE) 之後的第二個地址，也就是存放 JOE 的CFA之處adr2。 DUP 2+ 取得 (MAKE) 之後的第三個地址adr3，也就是我們所 要執行的碼的起始處。這時的堆疊註解是 ( adr1 adr2 adr3 -- ) SWAP @ >BODY 先取得 JOE 的執行區地址，再轉為參數區地址，也 就是存放著向量的地方。 ! 將所要執行的碼（CR）的地址adr3視為一個向量存入 。現在，JOE 指著 TEST 這個定義中的某處。當我們 鍵入JOE 時，那段碼就會被執行。 @ ?DUP IF >R THEN 讀取存著0的那個地址。因為是0，所以 IF THEN 的 片語不會被執行。 這是最基本的概念。但那個存著0的地方是做什麼用的？是給 ;AND 使用的。如果我們 把 TEST 的定義修改為 : TEST MAKE JOE CR ;AND SPACE ; 當執行 TEST 時，會先使 JOE 指向 CR，接著執行 SPACE 這個字。新版的 TEST 在詞典 中看起來像這樣： ┌──────────────┐
│ ↓
┌──┬────┬──┬───┬───┬───┬───┬───┐
│ │ cfa of │adr │cfa of│cfa of│cfa of│cfa of│cfa of│
│TEST│ (MAKE) │ │JOE │CR │EXIT │SPACE │EXIT │
└──┴────┴──┴───┴───┴───┴───┴───┘
下面是 ;AND 的定義： : ;AND COMPILE EXIT HERE MARKER @ ! ; IMMEDIATE 『;AND』編入了一個『EXIT』，就像『;』一樣。 回想一下，MAKE 會將一個地址存在變數 MARKER 內。接下來的 ;AND 會將那第二段 以字 SPACE 為起始的碼的地址（由 HERE 取得）存入剛才存著0的那個位置內。現在， (MAKE) 有了一個能繼續執行下去的指標了。片語 IF >R THEN 將把 SPACE 所在的地址放到返回堆疊上。因此，MAKE 到 ;AND 的這段碼就被跳過，而 執行會由 SPACE 再繼續，直到分號為止。 UNDO 這個字會將一個DOER字的行為再度變成什麼也不做。 最後要注意：在某些系統，你可能會有問題。如果你在冒號定義之外使用 MAKE 去定義一個前向參考，你或許可能無法找到最後被定義出來的那個字。例如你寫 : REFRAIN DO-DAH DO-DAH ;
MAKE SONG CHORUS REFRAIN ;
你的系統也許會認為 REFRAIN 是個尚未被定義的字。這個問題是因為 SMUDGE 的運作所 造成。解決的方法是，試著重新安排定義的順序，或是將 MAKE 的動作放到一個冒號定義 中，再去執行這個定義： : SETUP MAKE SONG CHORUS REFRAIN ; SETUP 在LMI公司的PC/FORTH 2.0系統的實現碼中，UNSMUDGE 的出現就是為了解決這個問題。 最後面有一個使用MAKE/DOER的例子。在載入這個例子到系統之後，先執行一次 RECITAL。再執行 WHY? 這個字。每次 WHY? 的執行，都會印出一個不同的理由。 \ FORTH83 Laxen/Perry/Harris 的版本
: NOTHING ;
: DOER CREATE ['] NOTHING >BODY , DOES> @ >R ;
VARIABLE MARKER
: (MAKE) R> DUP 2+ DUP 2+ SWAP @ >BODY !
@ ?DUP IF >R THEN ;
: MAKE STATE @ IF ( compiling)
COMPILE (MAKE) HERE MARKER ! 0 ,
ELSE HERE [COMPILE] ' >BODY ! [COMPILE] ] THEN ; IMMEDIATE
: ;AND COMPILE EXIT HERE MARKER @ ! ;
: UNDO ['] NOTHING >BODY [COMPILE] ' >BODY ! ;
\ FORTH83 LMI PC/FORTH 2.0 的版本
: NOTHING ;
: DOER CREATE ['] NOTHING >BODY , DOES> @ >R ;
VARIABLE MARKER
: (MAKE) R> DUP 2+ DUP 2+ SWAP @ >BODY !
@ ?DUP IF >R THEN ;
: MAKE STATE @ IF ( compiling)
COMPILE (MAKE) HERE MARKER ! 0 ,
ELSE HERE [COMPILE] ' >BODY ! [COMPILE] ] UNSMUDGE
THEN ; IMMEDIATE
: ;AND COMPILE EXIT HERE MARKER @ ! ;
: UNDO ['] NOTHING >BODY [COMPILE] ' >BODY ! ;
\ 一個例子
DOER ANSWER
: RECITAL
CR ." Your daddy is standing on the table. Ask him 'WHY?' "
MAKE ANSWER ." To change the light bulb."
BEGIN
MAKE ANSWER ." Because it's burned out."
MAKE ANSWER ." Because it was old."
MAKE ANSWER ." Because we put it there a long time age."
MAKE ANSWER ." Because it was dark!"
MAKE ANSWER ." Because it was night time."
MAKE ANSWER ." Stop saying WHY?"
MAKE ANSWER ." Because it's driving me crazy."
MAKE ANSWER ." Just let me change this light bulb!"
FALSE UNTIL ;
: WHY? CR ANSWER QUIT ;
|